Cleanup CMake code (Windows-specific)

Prepare for a more modern CMake version than the current minimum. - Use CMAKE_MSVC_RUNTIME_LIBRARY instead of the custom MSVC_CRT_TYPE. - Replace CMAKE_{C,CXX}_FLAGS modifications with add_compile_definitions/options and add_link_options. The older method already broke with new pcre2. - Fix clang-cl compilation and ASAN build. - Avoid modifying CMAKE_C_STANDARD_LIBRARIES/CMAKE_CXX_STANDARD_LIBRARIES, as this is discouraged by CMake. - Reduce system checks.
2025-07-21 23:40:10 +00:00 · 2025-04-03 12:25:44 +02:00
parent ff4209fa0d
commit b005b6097f
9 changed files with 235 additions and 395 deletions
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@ -31,7 +31,7 @@ ENDIF()
 # in RPM's:

 #set(CPACK_RPM_SPEC_MORE_DEFINE "%define __spec_install_post /bin/true")
-FOREACH(p CMP0022 CMP0046 CMP0040 CMP0048 CMP0054 CMP0056 CMP0067 CMP0074 CMP0075 CMP0069 CMP0135)
+FOREACH(p CMP0022 CMP0046 CMP0040 CMP0048 CMP0054 CMP0056 CMP0067 CMP0074 CMP0075 CMP0069 CMP0135 CMP0091)
  IF(POLICY ${p})
    CMAKE_POLICY(SET ${p} NEW)
  ENDIF()
--- a/cmake/os/Windows.cmake
+++ b/cmake/os/Windows.cmake
@ -15,372 +15,212 @@

 # This file includes Windows specific hacks, mostly around compiler flags

-INCLUDE (CheckCSourceCompiles)
-INCLUDE (CheckCXXSourceCompiles)
-INCLUDE (CheckStructHasMember)
-INCLUDE (CheckLibraryExists)
-INCLUDE (CheckFunctionExists)
-INCLUDE (CheckCSourceRuns)
-INCLUDE (CheckSymbolExists)
-INCLUDE (CheckTypeSize)

-IF(MSVC)
-  IF(CMAKE_CXX_COMPILER_ARCHITECTURE_ID STREQUAL ARM64)
-   SET(MSVC_ARM64 1)
-   SET(MSVC_INTEL 0)
-  ELSE()
-   SET(MSVC_INTEL 1)
-  ENDIF()
-ENDIF()
+if(MSVC)
+  if(CMAKE_CXX_COMPILER_ARCHITECTURE_ID STREQUAL ARM64)
+   set(MSVC_ARM64 1)
+   set(MSVC_INTEL 0)
+  else()
+   set(MSVC_INTEL 1)
+  endif()
+  if(CMAKE_CXX_COMPILER_ID STREQUAL Clang)
+   set(CLANG_CL TRUE)
+  endif()
+endif()

 # avoid running system checks by using pre-cached check results
 # system checks are expensive on VS since every tiny program is to be compiled in 
 # a VC solution.
-GET_FILENAME_COMPONENT(_SCRIPT_DIR ${CMAKE_CURRENT_LIST_FILE} PATH)
-INCLUDE(${_SCRIPT_DIR}/WindowsCache.cmake)
- 
+get_filename_component(_SCRIPT_DIR ${CMAKE_CURRENT_LIST_FILE} PATH)
+include(${_SCRIPT_DIR}/WindowsCache.cmake)

 # OS display name (version_compile_os etc).
-# Used by the test suite to ignore bugs on some platforms, 
-IF(CMAKE_SIZEOF_VOID_P MATCHES 8)
-  SET(SYSTEM_TYPE "Win64")
-ELSE()
-  SET(SYSTEM_TYPE "Win32")
-ENDIF()
+# Used by the test suite to ignore bugs on some platforms
+if(CMAKE_SIZEOF_VOID_P EQUAL 8)
+  set(SYSTEM_TYPE "Win64")
+else()
+  set(SYSTEM_TYPE "Win32")
+endif()

-# Intel compiler is almost Visual C++
-# (same compile flags etc). Set MSVC flag
-IF(CMAKE_C_COMPILER MATCHES "icl")
- SET(MSVC TRUE)
-ENDIF()
+function(find_asan_runtime result_list)
+  set(${result_list} "" PARENT_SCOPE)
+  if(CMAKE_C_COMPILER_VERSION)
+    set(CLANG_VERSION "${CMAKE_C_COMPILER_VERSION}")
+  else()
+    return()
+  endif()

-IF(MSVC  AND CMAKE_CXX_COMPILER_ID MATCHES Clang)
- SET(CLANG_CL TRUE)
-ENDIF()
+  get_filename_component(CLANG_BIN_DIR "${CMAKE_C_COMPILER}" DIRECTORY)
+  get_filename_component(LLVM_ROOT "${CLANG_BIN_DIR}" DIRECTORY)

-ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
-ADD_DEFINITIONS(-D_WIN32_WINNT=0x0A00)
-# We do not want the windows.h , or winsvc.h macros min/max
-ADD_DEFINITIONS(-DNOMINMAX -DNOSERVICE)
-# Speed up build process excluding unused header files
-ADD_DEFINITIONS(-DWIN32_LEAN_AND_MEAN)
-  
-# Adjust compiler and linker flags
-IF(MINGW AND CMAKE_SIZEOF_VOID_P EQUAL 4)
-   # mininal architecture flags, i486 enables GCC atomics
-  ADD_DEFINITIONS(-march=i486)
-ENDIF()
-
-MACRO(ENABLE_SANITIZERS)
-  IF(NOT  MSVC)
-    MESSAGE(FATAL_ERROR "clang-cl or MSVC necessary to enable asan/ubsan")
-  ENDIF()
-  # currently, asan is broken with static CRT.
-  IF(CLANG_CL AND NOT(MSVC_CRT_TYPE STREQUAL "/MD"))
-    SET(MSVC_CRT_TYPE "/MD" CACHE  INTERNAL "" FORCE)
-  ENDIF()
-  IF(CMAKE_SIZEOF_VOID_P EQUAL 4)
-    SET(ASAN_ARCH i386)
-  ELSE()
-    SET(ASAN_ARCH x86_64)
-  ENDIF()
-
-   # After installation, clang lib directory should be added to PATH
-  # (e.g C:/Program Files/LLVM/lib/clang/5.0.1/lib/windows)
-  SET(SANITIZER_LIBS)
-  SET(SANITIZER_LINK_LIBRARIES)
-  SET(SANITIZER_COMPILE_FLAGS)
-  IF(WITH_ASAN)
-    IF(CLANG_CL)
-      LIST(APPEND SANITIZER_LIBS
-        clang_rt.asan_dynamic-${ASAN_ARCH}.lib clang_rt.asan_dynamic_runtime_thunk-${ASAN_ARCH}.lib)
-    ENDIF()
-    STRING(APPEND SANITIZER_COMPILE_FLAGS " -fsanitize=address")
-  ENDIF()
-  IF(WITH_UBSAN)
-    STRING(APPEND SANITIZER_COMPILE_FLAGS " -fsanitize=undefined -fno-sanitize=alignment")
-  ENDIF()
-  FOREACH(lib ${SANITIZER_LIBS})
-    FIND_LIBRARY(${lib}_fullpath ${lib})
-    IF(NOT ${lib}_fullpath)
-      MESSAGE(FATAL_ERROR "Can't enable sanitizer : missing ${lib}")
-    ENDIF()
-    LIST(APPEND CMAKE_REQUIRED_LIBRARIES ${${lib}_fullpath})
-    STRING(APPEND CMAKE_C_STANDARD_LIBRARIES " \"${${lib}_fullpath}\" ")
-    STRING(APPEND CMAKE_CXX_STANDARD_LIBRARIES " \"${${lib}_fullpath}\" ")
-  ENDFOREACH()
-  STRING(APPEND CMAKE_C_FLAGS ${SANITIZER_COMPILE_FLAGS})
-  STRING(APPEND CMAKE_CXX_FLAGS ${SANITIZER_COMPILE_FLAGS})
-ENDMACRO()
-
-
-IF(MSVC)
-  IF(MSVC_VERSION LESS 1920)
-    MESSAGE(FATAL_ERROR "Visual Studio 2019 or later is required")
-  ENDIF()
-  # Disable mingw based pkg-config found in Strawberry perl
-  SET(PKG_CONFIG_EXECUTABLE 0 CACHE INTERNAL "")
-
-  SET(MSVC_CRT_TYPE /MD CACHE STRING
-    "Runtime library - specify runtime library for linking (/MT,/MTd,/MD,/MDd)"
+  # Determine target architecture
+  execute_process(
+    COMMAND "${CMAKE_C_COMPILER}" --version
+    OUTPUT_VARIABLE CLANG_VERSION_OUTPUT
+    OUTPUT_STRIP_TRAILING_WHITESPACE
+    ERROR_QUIET
  )
-  SET(VALID_CRT_TYPES /MTd /MDd /MD /MT)
-  IF (NOT ";${VALID_CRT_TYPES};" MATCHES ";${MSVC_CRT_TYPE};")
-    MESSAGE(FATAL_ERROR "Invalid value ${MSVC_CRT_TYPE} for MSVC_CRT_TYPE, choose one of /MT,/MTd,/MD,/MDd ")
-  ENDIF()

-  # CMake version 3.15 and later uses CMAKE_MSVC_RUNTIME_LIBRARY
-  # variable for our MSVC_CRT_TYPE.
-  # Set CMAKE_MSVC_RUNTIME_LIBRARY and pass to external projects
-  # it is important to keep the same CRT type when linking
-  #
-  # Translation rules MSVC_CRT_TYPE -> CMAKE_MSVC_RUNTIME_LIBRARY
-  # /MT  -> MultiThreaded
-  # /MTd -> MultiThreadedDebug
-  # /MD  -> MultiThreadedDLL
-  # /MDd -> MultiThreadedDebugDLL
+  if(CLANG_VERSION_OUTPUT MATCHES "x86_64")
+    set(ARCH_SUFFIX "x86_64")
+  elseif(CLANG_VERSION_OUTPUT MATCHES "i686|i386")
+    set(ARCH_SUFFIX "i386")
+  elseif(CLANG_VERSION_OUTPUT MATCHES "aarch64")
+    set(ARCH_SUFFIX "aarch64")
+  else()
+    message(FATAL_ERROR "unknown arch")
+  endif()

-  SET(CMAKE_MSVC_RUNTIME_LIBRARY MultiThreaded)
-  IF(MSVC_CRT_TYPE MATCHES "d$")
-    STRING(APPEND CMAKE_MSVC_RUNTIME_LIBRARY Debug)
-  ENDIF()
-  IF(MSVC_CRT_TYPE MATCHES "D")
-    STRING(APPEND CMAKE_MSVC_RUNTIME_LIBRARY DLL)
-  ENDIF()
+  string(REGEX MATCH "^[0-9]+" CLANG_MAJOR_VERSION "${CMAKE_C_COMPILER_VERSION}")
+  set(CLANG_VERSION_DIR "${LLVM_ROOT}/lib/clang/${CLANG_MAJOR_VERSION}")

-  IF(MSVC_CRT_TYPE MATCHES "/MD")
-   # Dynamic runtime (DLLs), need to install CRT libraries.
-   SET(CMAKE_INSTALL_SYSTEM_RUNTIME_COMPONENT VCCRT)
-   SET(CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS_NO_WARNINGS TRUE)
-   IF(MSVC_CRT_TYPE STREQUAL "/MDd")
-     SET (CMAKE_INSTALL_DEBUG_LIBRARIES_ONLY TRUE)
-   ENDIF()
-   INCLUDE(InstallRequiredSystemLibraries)
-  ENDIF()
-
-  IF(WITH_ASAN AND (NOT CLANG_CL))
-    SET(DYNAMIC_UCRT_LINK_DEFAULT OFF)
-  ELSE()
-    SET(DYNAMIC_UCRT_LINK_DEFAULT ON)
-  ENDIF()
-
-  OPTION(DYNAMIC_UCRT_LINK "Link Universal CRT dynamically, if MSVC_CRT_TYPE=/MT" ${DYNAMIC_UCRT_LINK_DEFAULT})
-  SET(DYNAMIC_UCRT_LINKER_OPTION " /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
-
-  # Enable debug info also in Release build,
-  # and create PDB to be able to analyze crashes.
-  FOREACH(type EXE SHARED MODULE)
-   SET(CMAKE_${type}_LINKER_FLAGS_RELEASE
-     "${CMAKE_${type}_LINKER_FLAGS_RELEASE} /debug")
-   SET(CMAKE_${type}_LINKER_FLAGS_MINSIZEREL
-     "${CMAKE_${type}_LINKER_FLAGS_MINSIZEREL} /debug")
-  ENDFOREACH()
-  
-  # Force runtime libraries
-  # Compile with /Zi to get debugging information
-
-  FOREACH(lang C CXX)
-    SET(CMAKE_${lang}_FLAGS_RELEASE "${CMAKE_${lang}_FLAGS_RELEASE} /Zi")
-  ENDFOREACH()
-  FOREACH(flag
-   CMAKE_C_FLAGS CMAKE_CXX_FLAGS
-   CMAKE_C_FLAGS_INIT CMAKE_CXX_FLAGS_INIT
-   CMAKE_C_FLAGS_RELEASE    CMAKE_C_FLAGS_RELWITHDEBINFO 
-   CMAKE_C_FLAGS_DEBUG      CMAKE_C_FLAGS_DEBUG_INIT 
-   CMAKE_CXX_FLAGS_RELEASE  CMAKE_CXX_FLAGS_RELWITHDEBINFO
-   CMAKE_CXX_FLAGS_DEBUG    CMAKE_CXX_FLAGS_DEBUG_INIT
-   CMAKE_C_FLAGS_MINSIZEREL  CMAKE_CXX_FLAGS_MINSIZEREL
-   )
-   STRING(REGEX REPLACE "/M[TD][d]?"  "${MSVC_CRT_TYPE}" "${flag}"  "${${flag}}" )
-   STRING(REPLACE "/ZI " "/Zi "  "${flag}"  "${${flag}}")
-   IF((NOT "${${flag}}" MATCHES "/Zi") AND (NOT "${${flag}}" MATCHES "/Z7"))
-    STRING(APPEND ${flag} " /Zi")
-   ENDIF()
-   # Remove inlining flags, added by CMake, if any.
-   # Compiler default is fine.
-   STRING(REGEX REPLACE "/Ob[0-3]" "" "${flag}"  "${${flag}}" )
-  ENDFOREACH()
-
-  # Allow to overwrite the inlining flag
-  SET(MSVC_INLINE "" CACHE STRING
-    "MSVC Inlining option, either empty, or one of /Ob0,/Ob1,/Ob2,/Ob3")
-  IF(MSVC_INLINE MATCHES "/Ob[0-3]")
-    ADD_COMPILE_OPTIONS(${MSVC_INLINE})
-  ELSEIF(NOT(MSVC_INLINE STREQUAL ""))
-    MESSAGE(FATAL_ERROR "Invalid option for MSVC_INLINE")
-  ENDIF()
-
-  IF(WITH_ASAN OR WITH_UBSAN)
-    # Workaround something Linux specific
-    SET(SECURITY_HARDENED 0 CACHE INTERNAL "" FORCE)
-    ENABLE_SANITIZERS()
-  ENDIF()
-
-  IF(CLANG_CL)
-     SET(CLANG_CL_FLAGS
-"-Wno-unknown-warning-option -Wno-unused-private-field \
-Wno-unused-parameter -Wno-inconsistent-missing-override \
-Wno-unused-command-line-argument -Wno-pointer-sign \
-Wno-deprecated-register -Wno-missing-braces \
-Wno-unused-function -Wno-unused-local-typedef -msse4.2 "
-    )
-    IF(CMAKE_SIZEOF_VOID_P MATCHES 8)
-      STRING(APPEND CLANG_CL_FLAGS "-mpclmul ")
+  set(out)
+  foreach(name clang_rt.asan_dynamic-${ARCH_SUFFIX}.lib
+               clang_rt.asan_dynamic_runtime_thunk-${ARCH_SUFFIX}.lib)
+    set(path "${CLANG_VERSION_DIR}/lib/windows/${name}")
+    if(EXISTS "${path}")
+      list(APPEND out ${path})
+    else()
+      message(FATAL_ERROR "expected library ${path} not found")
    ENDIF()
-    STRING(APPEND CMAKE_C_FLAGS " ${CLANG_CL_FLAGS} ${MSVC_CRT_TYPE}")
-    STRING(APPEND CMAKE_CXX_FLAGS " ${CLANG_CL_FLAGS}  ${MSVC_CRT_TYPE}")
-  ENDIF()
+  endforeach()
+  set(${result_list} ${out} PARENT_SCOPE)
+endfunction()

-  FOREACH(type EXE SHARED MODULE)
-   STRING(REGEX REPLACE "/STACK:([^ ]+)" "" CMAKE_${type}_LINKER_FLAGS "${CMAKE_${type}_LINKER_FLAGS}")
-   IF(WITH_ASAN)
-     SET(build_types RELWITHDEBINFO DEBUG)
-   ELSE()
-     SET(build_types RELWITHDEBINFO)
-   ENDIF()
-   FOREACH(btype ${build_types})
-     STRING(REGEX REPLACE "/INCREMENTAL:([^ ]+)" "/INCREMENTAL:NO" CMAKE_${type}_LINKER_FLAGS_${btype} "${CMAKE_${type}_LINKER_FLAGS_${btype}}")
-     STRING(REGEX REPLACE "/INCREMENTAL$" "/INCREMENTAL:NO" CMAKE_${type}_LINKER_FLAGS_${btype} "${CMAKE_${type}_LINKER_FLAGS_${btype}}")
-   ENDFOREACH()
-   IF(NOT CLANG_CL)
-     STRING(APPEND CMAKE_${type}_LINKER_FLAGS_RELWITHDEBINFO " /release /OPT:REF,ICF")
-   ENDIF()
-   IF(DYNAMIC_UCRT_LINK AND (MSVC_CRT_TYPE STREQUAL "/MT"))
-     FOREACH(config RELEASE RELWITHDEBINFO DEBUG MINSIZEREL)
-       STRING(APPEND CMAKE_${type}_LINKER_FLAGS_${config} ${DYNAMIC_UCRT_LINKER_OPTION})
-     ENDFOREACH()
-   ENDIF()
-  ENDFOREACH()
+macro(enable_sanitizers)
+  # Remove the runtime checks from the compiler flags
+  # ASAN does the same thing, in many cases better
+  foreach(lang C CXX)
+    foreach(suffix "_DEBUG" "_DEBUG_INIT")
+      string(REGEX REPLACE "/RTC[1su]" "" CMAKE_${lang}_FLAGS${suffix} "${CMAKE_${lang}_FLAGS${suffix}}")
+    endforeach()
+  endforeach()
+
+  if(WITH_ASAN)
+    add_compile_options($<$<COMPILE_LANGUAGE:C,CXX>:/fsanitize=address>)
+  endif()
+  if(WITH_UBSAN)
+    include(CheckCCompilerFlag)
+    check_c_compiler_flag(/fsanitize=undefined HAVE_fsanitize_undefined)
+    if (HAVE_fsanitize_undefined)
+      add_compile_options($<$<COMPILE_LANGUAGE:C,CXX>:/fsanitize=undefined>)
+    else()
+      message(FATAL_ERROR "UBSAN not supported by this compiler yet")
+    endif()
+  endif()
+  if(CLANG_CL)
+    find_asan_runtime(asan_libs)
+    foreach(lib ${asan_libs})
+      link_libraries(${lib})
+      string(APPEND CMAKE_C_STANDARD_LIBRARIES " \"${lib}\"")
+      string(APPEND CMAKE_CXX_STANDARD_LIBRARIES " \"${lib}\"")
+    endforeach()
+  else()
+    add_link_options(/INCREMENTAL:NO)
+  endif()
+endmacro()
+
+
+if(MSVC)
+  # Disable mingw based pkg-config found in Strawberry perl
+  set(PKG_CONFIG_EXECUTABLE 0 CACHE INTERNAL "")
+
+  if(NOT DEFINED CMAKE_MSVC_RUNTIME_LIBRARY)
+    set(CMAKE_MSVC_RUNTIME_LIBRARY MultiThreadedDLL)
+  endif()
+
+  if(CMAKE_MSVC_RUNTIME_LIBRARY MATCHES "DLL")
+    # Dynamic runtime (DLLs), need to install CRT libraries.
+    set(CMAKE_INSTALL_SYSTEM_RUNTIME_COMPONENT VCCRT)
+    set(CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS_NO_WARNINGS TRUE)
+    if(CMAKE_MSVC_RUNTIME_LIBRARY STREQUAL "MultiThreadedDebugDLL")
+      set(CMAKE_INSTALL_DEBUG_LIBRARIES_ONLY TRUE)
+    endif()
+    include(InstallRequiredSystemLibraries)
+  endif()
+
+  # Compile with /Zi to get debugging information
+  if (NOT DEFINED CMAKE_MSVC_DEBUG_INFORMATION_FORMAT)
+    set(CMAKE_MSVC_DEBUG_INFORMATION_FORMAT "ProgramDatabase")
+    add_link_options(/DEBUG) # Ensure debugging info at link time
+  endif()
+
+  if(WITH_ASAN OR WITH_UBSAN)
+    # Workaround something Linux specific
+    set(SECURITY_HARDENED 0 CACHE INTERNAL "" FORCE)
+    enable_sanitizers()
+  endif()
+
+  add_compile_definitions(
+    _CRT_SECURE_NO_DEPRECATE
+    _CRT_NONSTDC_NO_WARNINGS
+    _WIN32_WINNT=0x0A00
+    # We do not want the windows.h , or winsvc.h macros min/max
+    NOMINMAX NOSERVICE
+    # Speed up build process excluding unused header files
+    WIN32_LEAN_AND_MEAN
+  )
+  if(CLANG_CL)
+    add_compile_options(
+      -Wno-unknown-warning-option
+      -Wno-unused-private-field
+      -Wno-unused-parameter
+      -Wno-inconsistent-missing-override
+      -Wno-unused-command-line-argument
+      -Wno-pointer-sign
+      -Wno-deprecated-register
+      -Wno-missing-braces
+      -Wno-unused-function
+      -Wno-unused-local-typedef
+      -Wno-microsoft-static-assert
+      -Wno-c++17-extensions
+      -msse4.2
+    )
+    if((CMAKE_SIZEOF_VOID_P MATCHES 8) AND MSVC_INTEL)
+      add_compile_options(-mpclmul)
+    endif()
+  endif()

-  
  # Mark 32 bit executables large address aware so they can 
  # use > 2GB address space
-  IF(CMAKE_SIZEOF_VOID_P MATCHES 4)
-   STRING(APPEND CMAKE_EXE_LINKER_FLAGS " /LARGEADDRESSAWARE")
-  ENDIF()
-  
-  # Speed up multiprocessor build
-  IF (NOT CLANG_CL)
-    STRING(APPEND CMAKE_C_FLAGS " /MP")
-    STRING(APPEND CMAKE_CXX_FLAGS " /MP")
-    STRING(APPEND CMAKE_C_FLAGS_RELWITHDEBINFO " /Gw")
-    STRING(APPEND CMAKE_CXX_FLAGS_RELWITHDEBINFO " /Gw")
-  ENDIF()
-  
-  #TODO: update the code and remove the disabled warnings
-  STRING(APPEND CMAKE_C_FLAGS " /we4700 /we4311 /we4477 /we4302 /we4090")
-  STRING(APPEND CMAKE_CXX_FLAGS " /we4099 /we4700 /we4311 /we4477 /we4302 /we4090")
-  IF(MSVC_VERSION GREATER 1910  AND NOT CLANG_CL)
-    STRING(APPEND CMAKE_CXX_FLAGS " /permissive-")
-    STRING(APPEND CMAKE_C_FLAGS " /diagnostics:caret")
-    STRING(APPEND CMAKE_CXX_FLAGS " /diagnostics:caret")
-  ENDIF()
-  ADD_DEFINITIONS(-D_CRT_NONSTDC_NO_WARNINGS)
-  IF(MYSQL_MAINTAINER_MODE MATCHES "ERR")
-    STRING(APPEND CMAKE_C_FLAGS " /WX")
-    STRING(APPEND CMAKE_CXX_FLAGS " /WX")
-    FOREACH(type EXE SHARED MODULE)
-      FOREACH(cfg RELEASE DEBUG RELWITHDEBINFO)
-        SET(CMAKE_${type}_LINKER_FLAGS_${cfg} "${CMAKE_${type}_LINKER_FLAGS_${cfg}} /WX")
-      ENDFOREACH()
-    ENDFOREACH()
-  ENDIF()
+  if(CMAKE_SIZEOF_VOID_P MATCHES 4)
+    add_link_options(/LARGEADDRESSAWARE)
+  endif()

-  IF(FAST_BUILD)
-    STRING (REGEX REPLACE "/RTC(su|[1su])" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
-  ELSEIF (NOT CLANG_CL)
-    STRING(APPEND CMAKE_CXX_FLAGS_RELEASE " /d2OptimizeHugeFunctions")
-    STRING(APPEND CMAKE_CXX_FLAGS_RELWITHDEBINFO " /d2OptimizeHugeFunctions")
-  ENDIF()
-  ADD_COMPILE_OPTIONS($<$<COMPILE_LANGUAGE:C,CXX>:/utf-8>)
-ENDIF()
+  # RelWithDebInfo is deoptimized wrt inlining.
+  # Fix it to default
+  foreach(lang C CXX)
+    foreach(suffix "_RELWITHDEBINFO" "_RELWITHDEBINFO_INIT")
+      string(REGEX REPLACE "/Ob[0-1]" "" CMAKE_${lang}_FLAGS${suffix} "${CMAKE_${lang}_FLAGS${suffix}}")
+    endforeach()
+  endforeach()

-# Always link with socket/synchronization libraries
-STRING(APPEND CMAKE_C_STANDARD_LIBRARIES " ws2_32.lib synchronization.lib")
-STRING(APPEND CMAKE_CXX_STANDARD_LIBRARIES " ws2_32.lib synchronization.lib")
+  if(NOT CLANG_CL)
+    add_link_options("$<$<CONFIG:Release,RelWithDebInfo>:/INCREMENTAL:NO;/RELEASE;/OPT:REF,ICF>")
+    add_compile_options($<$<COMPILE_LANGUAGE:C,CXX>:$<$<CONFIG:Release,RelWithDebInfo>:/Gw>>)
+    add_compile_options($<$<COMPILE_LANGUAGE:C,CXX>:/MP>)
+    add_compile_options("$<$<COMPILE_LANGUAGE:C,CXX>:/we4099;/we4700;/we4311;/we4477;/we4302;/we4090>")
+    add_compile_options($<$<COMPILE_LANGUAGE:CXX>:/permissive->)
+    add_compile_options($<$<COMPILE_LANGUAGE:C,CXX>:/diagnostics:caret>)
+    add_compile_options($<$<COMPILE_LANGUAGE:C,CXX>:/utf-8>)
+    if(NOT FAST_BUILD)
+      add_compile_options($<$<CONFIG:Release,RelWithDebInfo>:$<$<COMPILE_LANGUAGE:C,CXX>:/d2OptimizeHugeFunctions>>)
+    endif()
+  endif()

-# System checks
-SET(SIGNAL_WITH_VIO_CLOSE 1) # Something that runtime team needs
-SET(HAVE_UNACCESSIBLE_AFTER_MEM_DECOMMIT 1)
+  if(MYSQL_MAINTAINER_MODE MATCHES "ERR")
+    set(CMAKE_COMPILE_WARNING_AS_ERROR ON)
+    add_link_options(/WX)
+  endif()
+endif()

-# IPv6 constants appeared in Vista SDK first. We need to define them in any case if they are 
-# not in headers, to handle dual mode sockets correctly.
-CHECK_SYMBOL_EXISTS(IPPROTO_IPV6 "winsock2.h" HAVE_IPPROTO_IPV6)
-IF(NOT HAVE_IPPROTO_IPV6)
-  SET(HAVE_IPPROTO_IPV6 41)
-ENDIF()
-CHECK_SYMBOL_EXISTS(IPV6_V6ONLY  "winsock2.h;ws2ipdef.h" HAVE_IPV6_V6ONLY)
-IF(NOT HAVE_IPV6_V6ONLY)
-  SET(IPV6_V6ONLY 27)
-ENDIF()
+# avoid running system checks by using pre-cached check results
+# system checks are expensive on VS generator
+get_filename_component(_SCRIPT_DIR ${CMAKE_CURRENT_LIST_FILE} PATH)
+include(${_SCRIPT_DIR}/WindowsCache.cmake)

-# Some standard functions exist there under different
-# names (e.g popen is _popen or strok_r is _strtok_s)
-# If a replacement function exists, HAVE_FUNCTION is
-# defined to 1. CMake variable <function_name> will also
-# be defined to the replacement name.
-# So for example, CHECK_FUNCTION_REPLACEMENT(popen _popen)
-# will define HAVE_POPEN to 1 and set variable named popen
-# to _popen. If the header template, one needs to have
-# cmakedefine popen @popen@ which will expand to 
-# define popen _popen after CONFIGURE_FILE
+# this is out of place, not really a system check
+set(FN_NO_CASE_SENSE 1)
+set(USE_SYMDIR 1)
+set(HAVE_UNACCESSIBLE_AFTER_MEM_DECOMMIT 1)

-MACRO(CHECK_FUNCTION_REPLACEMENT function replacement)
-  STRING(TOUPPER ${function} function_upper)
-  CHECK_FUNCTION_EXISTS(${function} HAVE_${function_upper})
-  IF(NOT HAVE_${function_upper})
-    CHECK_FUNCTION_EXISTS(${replacement}  HAVE_${replacement})
-    IF(HAVE_${replacement})
-      SET(HAVE_${function_upper} 1 )
-      SET(${function} ${replacement})
-    ENDIF()
-  ENDIF()
-ENDMACRO()
-MACRO(CHECK_SYMBOL_REPLACEMENT symbol replacement header)
-  STRING(TOUPPER ${symbol} symbol_upper)
-  CHECK_SYMBOL_EXISTS(${symbol} ${header} HAVE_${symbol_upper})
-  IF(NOT HAVE_${symbol_upper})
-    CHECK_SYMBOL_EXISTS(${replacement} ${header} HAVE_${replacement})
-    IF(HAVE_${replacement})
-      SET(HAVE_${symbol_upper} 1)
-      SET(${symbol} ${replacement})
-    ENDIF()
-  ENDIF()
-ENDMACRO()
-
-CHECK_SYMBOL_REPLACEMENT(S_IROTH _S_IREAD sys/stat.h)
-CHECK_SYMBOL_REPLACEMENT(S_IFIFO _S_IFIFO sys/stat.h)
-CHECK_SYMBOL_REPLACEMENT(SIGQUIT SIGTERM signal.h)
-CHECK_SYMBOL_REPLACEMENT(SIGPIPE SIGINT signal.h)
-CHECK_FUNCTION_REPLACEMENT(popen _popen)
-CHECK_FUNCTION_REPLACEMENT(pclose _pclose)
-CHECK_FUNCTION_REPLACEMENT(access _access)
-CHECK_FUNCTION_REPLACEMENT(strcasecmp _stricmp)
-CHECK_FUNCTION_REPLACEMENT(strncasecmp _strnicmp)
-CHECK_SYMBOL_REPLACEMENT(snprintf _snprintf stdio.h)
-CHECK_FUNCTION_REPLACEMENT(strtok_r strtok_s)
-CHECK_FUNCTION_REPLACEMENT(strtoll _strtoi64)
-CHECK_FUNCTION_REPLACEMENT(strtoull _strtoui64)
-CHECK_FUNCTION_REPLACEMENT(vsnprintf _vsnprintf)
-CHECK_TYPE_SIZE(ssize_t SIZE_OF_SSIZE_T)
-IF(NOT HAVE_SIZE_OF_SSIZE_T)
- SET(ssize_t SSIZE_T)
-ENDIF()
-
-SET(FN_NO_CASE_SENSE 1)
-SET(USE_SYMDIR 1)
-
-# Force static C runtime for targets in current directory
-# (useful to get rid of MFC dll's dependency, or in installer)
-MACRO(FORCE_STATIC_CRT)
-  FOREACH(flag
-    CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELWITHDEBINFO
-    CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_DEBUG_INIT
-    CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_RELWITHDEBINFO
-    CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_DEBUG_INIT
-    CMAKE_C_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_MINSIZEREL
-  )
-    STRING(REGEX REPLACE "/MD[d]?"  "/MT" "${flag}"  "${${flag}}" )
-    STRING(REPLACE "${DYNAMIC_UCRT_LINKER_OPTION}" "" "${flag}" "${${flag}}")
-  ENDFOREACH()
-ENDMACRO()
--- a/cmake/os/WindowsCache.cmake
+++ b/cmake/os/WindowsCache.cmake
@ -203,10 +203,10 @@ SET(HAVE_STRING_H 1 CACHE  INTERNAL "")
 SET(HAVE_STRNDUP CACHE  INTERNAL "")
 SET(HAVE_STRNLEN 1 CACHE  INTERNAL "")
 SET(HAVE_STRPBRK 1 CACHE  INTERNAL "")
-SET(HAVE_STRTOK_R CACHE  INTERNAL "")
-SET(HAVE_STRTOLL CACHE  INTERNAL "")
+SET(HAVE_STRTOK_R 1 CACHE  INTERNAL "")
+SET(HAVE_STRTOLL 1 CACHE  INTERNAL "")
 SET(HAVE_STRTOUL 1 CACHE  INTERNAL "")
-SET(HAVE_STRTOULL CACHE  INTERNAL "")
+SET(HAVE_STRTOULL 1 CACHE  INTERNAL "")
 SET(HAVE_SYNCH_H CACHE  INTERNAL "")
 SET(HAVE_SYSENT_H CACHE  INTERNAL "")
 SET(HAVE_SYS_DIR_H CACHE  INTERNAL "")
@ -294,6 +294,7 @@ SET(HAVE_EVENT_H CACHE INTERNAL "")
 SET(HAVE_LINUX_UNISTD_H CACHE INTERNAL "")
 SET(HAVE_SYS_UTSNAME_H CACHE INTERNAL "")
 SET(HAVE_PTHREAD_ATTR_GETGUARDSIZE CACHE INTERNAL "")
+SET(HAVE_PTHREAD_GETATTR_NP CACHE INTERNAL "")
 SET(HAVE_SOCKPEERCRED CACHE INTERNAL "")
 SET(HAVE_ABI_CXA_DEMANGLE CACHE INTERNAL "")
 SET(HAVE_GCC_C11_ATOMICS CACHE INTERNAL "")
@ -348,4 +349,16 @@ SET(HAVE_SYS_STATVFS_H CACHE  INTERNAL "")
 SET(HAVE_GETPAGESIZES CACHE INTERNAL "")
 SET(HAVE_LINUX_LIMITS_H CACHE INTERNAL "")
 SET(HAVE_FILE_UCONTEXT_H CACHE INTERNAL "")
+SET(have_C__Werror CACHE INTERNAL "")
+SET(HAVE_SIGNAL_H 1 CACHE INTERNAL "")
+SET(HAVE_UINT CACHE INTERNAL "")
+SET(HAVE_SOCKET_LEN_T CACHE INTERNAL "")
+SET(HAVE_GETTHRID CACHE INTERNAL "")
+SET(HAVE_THREAD_LOCAL 1 CACHE INTERNAL "")
+SET(have_CXX__Wno_unused_but_set_variable CACHE INTERNAL "")
+SET(HAVE_UNISTD_H CACHE INTERNAL "")
+SET(HAVE_LINUX_UNISTD_H CACHE INTERNAL "")
+SET(OFF64_T CACHE INTERNAL "")
+SET(Z_HAVE_UNISTD_H CACHE INTERNAL "")
+SET(HAVE_OFF64_T CACHE FALSE INTERNAL "")
 ENDIF(MSVC)
--- a/cmake/plugin.cmake
+++ b/cmake/plugin.cmake
@ -214,6 +214,11 @@ MACRO(MYSQL_ADD_PLUGIN)

    TARGET_LINK_LIBRARIES (${target} mysqlservices ${ARG_LINK_LIBRARIES})

+    IF(WIN32)
+      # A popular library, turns out many plugins need it for gethostname()
+      TARGET_LINK_LIBRARIES (${target} ws2_32)
+    ENDIF()
+
    IF(CMAKE_SYSTEM_NAME MATCHES AIX)
      TARGET_LINK_OPTIONS(${target} PRIVATE "-Wl,-bE:${CMAKE_SOURCE_DIR}/libservices/mysqlservices_aix.def")
    ENDIF()
--- a/config.h.cmake
+++ b/config.h.cmake
@ -402,38 +402,27 @@
 #cmakedefine SIGNAL_WITH_VIO_CLOSE 1

 /* Windows stuff, mostly functions, that have Posix analogs but named differently */
-#cmakedefine S_IROTH @S_IROTH@
-#cmakedefine S_IFIFO @S_IFIFO@
-#cmakedefine IPPROTO_IPV6 @IPPROTO_IPV6@
-#cmakedefine IPV6_V6ONLY @IPV6_V6ONLY@
-#cmakedefine sigset_t @sigset_t@
-#cmakedefine mode_t @mode_t@
-#cmakedefine SIGQUIT @SIGQUIT@
-#cmakedefine SIGPIPE @SIGPIPE@
-#cmakedefine popen @popen@
-#cmakedefine pclose @pclose@
-#cmakedefine ssize_t @ssize_t@
-#cmakedefine strcasecmp @strcasecmp@
-#cmakedefine strncasecmp @strncasecmp@
-#cmakedefine snprintf @snprintf@
-#cmakedefine strtok_r @strtok_r@
-#cmakedefine strtoll @strtoll@
-#cmakedefine strtoull @strtoull@
-#cmakedefine vsnprintf @vsnprintf@
-#if defined(_MSC_VER) && (_MSC_VER > 1800)
+#ifdef _WIN32
+#define S_IROTH _S_IREAD
+#define S_IFIFO _S_IFIFO
+#define SIGQUIT SIGTERM
+#define SIGPIPE SIGINT
+#define sigset_t int
+#define mode_t int
+#define popen _popen
+#define pclose _pclose
+#define ssize_t SSIZE_T
+#define strcasecmp _stricmp
+#define strncasecmp _strnicmp
+#define strtok_r strtok_s
 #define tzname _tzname
 #define P_tmpdir "C:\\TEMP"
-#endif
-#if defined(_MSC_VER) && (_MSC_VER > 1310)
-# define HAVE_SETENV
 #define setenv(a,b,c) _putenv_s(a,b)
-#endif
-#define PSAPI_VERSION 1     /* for GetProcessMemoryInfo() */

-/* We don't want the min/max macros */
-#ifdef _WIN32
+#define HAVE_SETENV
 #define NOMINMAX 1
-#endif
+#define PSAPI_VERSION 2     /* for GetProcessMemoryInfo() */
+#endif /* _WIN32 */

 /*
  MySQL features
--- a/mysys/CMakeLists.txt
+++ b/mysys/CMakeLists.txt
@ -171,7 +171,7 @@ IF(HAVE_BFD_H)
 ENDIF(HAVE_BFD_H)

 IF (WIN32)
-  TARGET_LINK_LIBRARIES(mysys iphlpapi dbghelp)
+  TARGET_LINK_LIBRARIES(mysys iphlpapi dbghelp ws2_32 synchronization)
 ENDIF(WIN32)

 # Need explicit pthread for gcc -fsanitize=address
--- a/storage/connect/CMakeLists.txt
+++ b/storage/connect/CMakeLists.txt
@ -413,14 +413,16 @@ IF(NOT TARGET connect)
  RETURN()
 ENDIF()

-IF(MSVC AND (CMAKE_CXX_FLAGS MATCHES "/MP"))
+IF(CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
  # domdoc.cpp uses compiler directive #import which is not compatible
  # with the /MP option, resulting in  compiler error C2813.
  # Remove /MP for this file.
+  GET_TARGET_PROPERTY(CURRENT_COMPILE_OPTIONS connect COMPILE_OPTIONS)
+  LIST(REMOVE_ITEM CURRENT_COMPILE_OPTIONS "$<$<COMPILE_LANGUAGE:C,CXX>:/MP>")
+  SET_TARGET_PROPERTIES(connect PROPERTIES COMPILE_OPTIONS "${CURRENT_COMPILE_OPTIONS}")
  SET(src_list ${CONNECT_SOURCES})
  LIST(FIND src_list  domdoc.cpp idx)
  IF(idx GREATER -1)
-    STRING(REPLACE "/MP" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
    LIST(REMOVE_AT src_list ${idx})
    SET_SOURCE_FILES_PROPERTIES(${src_list} PROPERTIES COMPILE_FLAGS "/MP")
  ENDIF()
--- a/win/packaging/ca/CMakeLists.txt
+++ b/win/packaging/ca/CMakeLists.txt
@ -18,7 +18,8 @@ SET(WIXCA_SOURCES CustomAction.cpp CustomAction.def)
 INCLUDE_DIRECTORIES(${CMAKE_SOURCE_DIR}/sql ${CMAKE_CURRENT_SOURCE_DIR} ${WIX_INCLUDE_DIR})

 # Custom action should not depend on C runtime, since we do not know if CRT is installed.
-FORCE_STATIC_CRT()
 ADD_VERSION_INFO(wixca SHARED WIXCA_SOURCES)
 ADD_LIBRARY(wixca SHARED EXCLUDE_FROM_ALL ${WIXCA_SOURCES} ${CMAKE_SOURCE_DIR}/sql/winservice.c)
-TARGET_LINK_LIBRARIES(wixca ${WIX_WCAUTIL_LIBRARY} ${WIX_DUTIL_LIBRARY} msi version)
+# Static linking with CRT, because it is called when MSVC libraries are not yet there,
+SET_TARGET_PROPERTIES(wixca PROPERTIES MSVC_RUNTIME_LIBRARY MultiThreaded)
+TARGET_LINK_LIBRARIES(wixca ${WIX_WCAUTIL_LIBRARY} ${WIX_DUTIL_LIBRARY} msi version ws2_32)
--- a/win/upgrade_wizard/CMakeLists.txt
+++ b/win/upgrade_wizard/CMakeLists.txt
@ -4,7 +4,6 @@ ENDIF()

 # We need MFC
 # /permissive- flag does not play well with MFC, disable it.
-STRING(REPLACE "/permissive-"  "" CMAKE_CXX_FLAGS  "${CMAKE_CXX_FLAGS}")
 REMOVE_DEFINITIONS(-DNOSERVICE) # fixes "already defined" warning in an AFX header

 FIND_PACKAGE(MFC)
@ -17,31 +16,22 @@ IF(NOT MFC_FOUND)
  RETURN()
 ENDIF()

-IF(MSVC_CRT_TYPE MATCHES "/MD")
-  # FORCE static CRT and MFC for upgrade wizard,
-  # so we do not have to redistribute MFC.
-  FORCE_STATIC_CRT()
-  SET(UPGRADE_WIZARD_SOURCES  ${CMAKE_SOURCE_DIR}/sql/winservice.c)
-ELSE()
-  SET(UPGRADE_WIZARD_LINK_LIBRARIES winservice)
-ENDIF()
-
 # MFC should be statically linked
 SET(CMAKE_MFC_FLAG 1)

 # Enable exception handling (avoids warnings)
-SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHsc -DNO_WARN_MBCS_MFC_DEPRECATION")
-
+ADD_DEFINITIONS(-DNO_WARN_MBCS_MFC_DEPRECATION)
 INCLUDE_DIRECTORIES(${CMAKE_SOURCE_DIR}/sql)
 MYSQL_ADD_EXECUTABLE(mariadb-upgrade-wizard
-  upgrade.cpp upgradeDlg.cpp upgrade.rc ${UPGRADE_WIZARD_SOURCES}
+  upgrade.cpp upgradeDlg.cpp
+  ${CMAKE_SOURCE_DIR}/sql/winservice.c
+  upgrade.rc
  COMPONENT Server)

-
-TARGET_LINK_LIBRARIES(mariadb-upgrade-wizard ${UPGRADE_WIZARD_LINK_LIBRARIES})
 # upgrade_wizard is Windows executable, set WIN32_EXECUTABLE so it does not
 # create a console.
 SET_TARGET_PROPERTIES(mariadb-upgrade-wizard PROPERTIES
  WIN32_EXECUTABLE 1
  LINK_FLAGS "/MANIFESTUAC:level='requireAdministrator'"
+  MSVC_RUNTIME_LIBRARY MultiThreaded
 )