# vim:set softtabstop=3 shiftwidth=3 tabstop=3 expandtab:

add_library(KF6ActivitiesStats)
add_library(KF6::ActivitiesStats ALIAS KF6ActivitiesStats)

set_target_properties(KF6ActivitiesStats PROPERTIES
   VERSION     ${KACTIVITIESSTATS_VERSION}
   SOVERSION   ${KACTIVITIESSTATS_SOVERSION}
   EXPORT_NAME ActivitiesStats
)

target_sources(KF6ActivitiesStats PRIVATE
   query.cpp
   terms.cpp
   resultset.cpp
   resultwatcher.cpp
   resultmodel.cpp
   activitiessync_p.cpp
   cleaning.cpp

   ${KASTATS_CURRENT_ROOT_SOURCE_DIR}/src/common/database/Database.cpp
   ${KASTATS_CURRENT_ROOT_SOURCE_DIR}/src/common/database/schema/ResourcesDatabaseSchema.cpp
   ${KASTATS_CURRENT_ROOT_SOURCE_DIR}/src/utils/qsqlquery_iterator.cpp
)

ecm_qt_declare_logging_category(KF6ActivitiesStats
    HEADER kactivities-stats-logsettings.h
    IDENTIFIER KACTIVITIES_STATS_LOG
    CATEGORY_NAME kf.activitiesstats
    OLD_CATEGORY_NAMES kf5.kactivity.stat
    DESCRIPTION "KActivities Stats"
    EXPORT KACTIVITIES_STATS
)

set(KActivitiesStats_DBus_SRCS)
qt_add_dbus_interface(KActivitiesStats_DBus_SRCS
   ${KASTATS_CURRENT_ROOT_SOURCE_DIR}/src/common/dbus/org.kde.ActivityManager.ResourcesScoring.xml
   resourcesscoring_interface
)
qt_add_dbus_interface(KActivitiesStats_DBus_SRCS
   ${KASTATS_CURRENT_ROOT_SOURCE_DIR}/src/common/dbus/org.kde.ActivityManager.ResourcesLinking.xml
   resourceslinking_interface
)

target_sources(KF6ActivitiesStats PRIVATE
   ${KActivitiesStats_DBus_SRCS}
)

target_link_libraries(KF6ActivitiesStats
   PUBLIC
      Qt6::Core
   PRIVATE
      Qt6::DBus
      Qt6::Sql
      KF6::Activities
      KF6::ConfigCore
      Threads::Threads
)

target_include_directories(KF6ActivitiesStats
   INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KActivitiesStats>"
)

# install
ecm_generate_export_header (KF6ActivitiesStats
   BASE_NAME KActivitiesStats
   GROUP_BASE_NAME KF
   VERSION ${KF6_MIN_VERSION}
   USE_VERSION_HEADER
   DEPRECATED_BASE_VERSION 0
)

ecm_generate_headers (
   KActivitiesStats_CamelCase_HEADERS
   HEADER_NAMES
   Query
   Terms
   ResultSet
   ResultWatcher
   ResultModel
   Cleaning

   PREFIX KActivitiesStats
   REQUIRED_HEADERS KActivitiesStats_HEADERS
)

install (
   TARGETS KF6ActivitiesStats
   EXPORT KF6ActivitiesStatsLibraryTargets
   ${KF_INSTALL_TARGETS_DEFAULT_ARGS}
   )

install (
   FILES ${KActivitiesStats_CamelCase_HEADERS}
   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KActivitiesStats/KActivities/Stats
   COMPONENT Devel
   )

install (
   FILES ${KActivitiesStats_HEADERS} ${CMAKE_CURRENT_BINARY_DIR}/kactivitiesstats_export.h
   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KActivitiesStats/kactivitiesstats
   COMPONENT Devel
   )

ecm_qt_install_logging_categories(
    EXPORT KACTIVITIES_STATS
    FILE kactivities-stats.categories
    DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
)

if(BUILD_QCH)
    ecm_add_qch(
        KF6ActivitiesStats_QCH
        NAME KActivitiesStats
        BASE_NAME KF6ActivitiesStats
        VERSION ${PROJECT_VERSION}
        ORG_DOMAIN org.kde
        SOURCES # using only public headers, to cover only public API
            ${KActivitiesStats_HEADERS}
        MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
        LINK_QCHS
            Qt6Core_QCH
            KF6Activities_QCH # while not in API symbols, some classes are referenced in comments
        INCLUDE_DIRS
            ${CMAKE_CURRENT_BINARY_DIR}
        BLANK_MACROS
            KACTIVITIESSTATS_EXPORT
            KACTIVITIESSTATS_DEPRECATED
            KACTIVITIESSTATS_DEPRECATED_EXPORT
        TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
        QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
        COMPONENT Devel
    )
endif()

if (NOT WIN32)
    ecm_generate_pkgconfig_file(BASE_NAME KF6ActivitiesStats
      LIB_NAME KF6ActivitiesStats
      INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KActivitiesStats
      DEPS Qt6Core
      DESCRIPTION "libKActivitiesStats is a C++ library for using KDE activities"
      INSTALL
    )
endif ()

